home *** CD-ROM | disk | FTP | other *** search
/ EnigmA Amiga Run 1997 June / EnigmA AMIGA RUN 19 (1997)(G.R. Edizioni)(IT)[!][issue 1997-06][EAR-CD III].iso / recent1 / fi-set_mui.lha / MUI / Install_MUI-Set < prev    next >
Text File  |  1996-09-26  |  21KB  |  534 lines
  1. ;---------------------------------------------------------
  2. ; $VER: FreshIconsV1.2.1-Softwareset-Installer Script 17. Mai 1997
  3. ; Version for the MUI-Package (MUI © by Stefan Stuntz)
  4. ; by Christian Taulien of Strange Intelligence
  5. ; German/English Language
  6. ; Script-Version: 1.4
  7. ; Copyright (C) 1997 Strange Intelligence
  8. ;/*S*/ // History
  9. ; 8. Mai 1997
  10. ;  Error removed error by City, reported by Ant.
  11. ;  It's now possible to install icons with spaces in the names
  12. ; 17. Mai 1997
  13. ;  Error removed by City, reported by Ant.
  14. ;  Occured when installing from "Ram Disk:" because of
  15. ;  the space-char.
  16. ;/*E*/
  17. ; *** Attention: Foldstart="/*S*/" and Foldstop="/*E*/" *** (I use GoldED)
  18.  
  19. ;/*S*/ Variables
  20. ;// Setup these variables to make this script work for your intention
  21. (set #dos_destination "MUI:")         ; Software-package path
  22. (set #f_requirements  0)              ; Set to 1 to display the requirements on start
  23. (set #f_onlyexisting  0)              ; Set to 0 to  switch on forced icon-install (not only if already existing)
  24.  
  25. ;// Do not modify if possible:
  26. (set #dos_freshdrawer "SYS:System/FreshIcons") ; Default Drawer of the installed FreshIcons
  27. (set #dos_backup_dest "SYS:Storage/") ; backup-directory
  28. (set #temp            "")             ; name of the temporaryfile
  29. (set #dos_toolsdir    "c/")           ; The Path to the tools
  30. (set #dos_source      "")             ; name of the new freshicon
  31. (set #dos_presource   "")             ; Basics drawer
  32. (set #dos_backupfile  "")             ; The file to backup
  33. (set #dos_filename    "")             ; Filename without .info
  34. (set #dos_filename_i  "")             ; Filename with .info
  35. (set #dos_args        "")             ; Parameterlist for the call of updateicon
  36. (set #updateicon_opts "")             ; options for update icons
  37. (set #f_Backup        0)              ; Backup yes or no
  38. (set #b_options       0)              ; Option-Flags for updateicon
  39. ;/*E*/
  40. ;---------------------------------------------------------
  41. ;/*S*/ Subroutines
  42. ;/*S*/ UP: english-strings
  43. (procedure P_englishinstall
  44. ; Definitions SW-Set-Specific
  45. (set #set_name                  "MUI")
  46.  
  47. ; Definitions common
  48. (set #ask_backup                "Shall a backup of all files to be modified be made?")
  49. (set #ask_WhereToBackup         (CAT "In which drawer the backupfiles shall be saved?\n(There, a drawer called \"" #set_name "\" will be created.)"))
  50. (set #ask_WhereFreshIcons       "Specify the  drawer of your installed FreshIcons-Package (Go into it!)")
  51. (set #ask_WherePackage          ( CAT "Specify your path to\"" #set_name "\"\n(Go into it!)"))
  52. (set #ask_options               "Which icon-properties shall i take over additionally?")
  53. (set #err_wronginstaller        "Your installer-program is too old. At least version 43 is required.\n\nIn the install-drawer of the FreshIcons this needed version is a copy of it.")
  54. (set #err_no_updateicon         "Could not find the FreshIcons-tool \"UpDateIcon\"\nNeither in C:, FreshIcons/c nor in current c/!")
  55. (set #err_nomakedir             "Couldn't create temporary-drawer!")
  56. (set #err_notemploc             "Couldn't localize temporary-drawer!")
  57. (set #err_desticonisdir         "The name of an icon to be installed is an existing dir. The icon will not be installed from the icon-set.")
  58. (set #gad_yes                   "Yes")
  59. (set #gad_no                    "No")
  60. (set #gad_opt_typ               "Icon type")
  61. (set #gad_opt_tooltype          "Tooltypes")
  62. (set #gad_opt_position          "Position")
  63. (set #gad_opt_deftool           "Default-Tool")
  64. (set #gad_opt_stack             "Stack-Size")
  65. (set #gad_opt_force             "Only already existing icons")
  66. (set #msg_makebackup            "Making backup of a file...")
  67. (set #msg_requirements          (CAT "Welcome to the installation of the FreshIcons-set for - " #set_name "\nThe following things are required:\n\nnone"))
  68. (set #msg_updateicon            "Modifying an icon...")
  69. (set #msg_installnewicon        "Installing new freshicons...")
  70. (set #msg_broken                (CAT #set_name "-IconSet Installation aborted!"))
  71. (set #msg_copyicon              "Copying an icon...")
  72. (set #help_backup               "Decide here, wether to make a backup of every single file to be changed by this installation-script.")
  73. (set #help_WhereToBackup        (CAT "Specify a drawer were to put all the backup files. For example: SYS:Storage/FreshIcons_Baks or so. A drawer \"" #set_name "_icons\"in it will be created automatically."))
  74. (set #help_WhereFreshIcons      "Here you shall specify the maindirectory of your installed version of the FreshIcons-package.\n\nIf you have installed the FreshIcons-package complete and did no changes in it, the predefined path should be set correct.")
  75. (set #help_WherePackage         (CAT "Here you shall specify the path your installed " #set_name "."))
  76. (set #help_requirements         "Hi-hoo! Make sure to fulfill the requirements!")
  77. (set #help_Options              "Here you shall specify each property which shall i take over from the icons in the icon set.")
  78. )
  79. ;/*E*/
  80. ;/*S*/ UP: german-string
  81. (procedure P_germaninstall
  82. ; Definitionen SW-Set-Specific
  83. (set #set_name                  "MUI")
  84. ; Definitionen common
  85. (set #ask_backup                "Soll ein Backup aller zu verändernden Dateien angefertigt werden?")
  86. (set #ask_WhereToBackup         (CAT "In welches Verzeichnis sollen die Dateien gesichert werden?\n(Es wird dort ein Verzeichnis \"" #set_name "_icons\" erstellt.)"))
  87. (set #ask_WhereFreshIcons       "Geben Sie Ihr FreshIcons-Hauptverzeichnis an!\n(In das Verzeichnis \"hineingehen\")")
  88. (set #ask_WherePackage          (CAT "Geben Sie den Pfad von \"" #set_name "\" an.\n(In das Verzeichnis \"hineingehen\".)"))
  89. (set #ask_options               "Welche Icon-Eigenschaften sollen zusätzlich aus dem Iconset übernommen werden?")
  90. (set #err_wronginstaller        "Ihr Installer-Programm ist zu alt. Es wird mindestens Version 43 benötigt.\n\nIm Install-Verzeichnis von FreshIcons ist diese Version enthalten.")
  91. (set #err_no_updateicon         "Ich konnte das FreshIcons-Programm \"UpDateIcon\" nicht finden.\n\nWeder im C:, FreshIcons/c noch im aktuellen c/ Verzeichnis!")
  92. (set #err_nomakedir             "Konnte temporäres Verzeichnis nicht erstellen!")
  93. (set #err_notemploc             "Konnte temporäres Verzeichnis nicht lokalisieren!")
  94. (set #err_desticonisdir         "Der Name eines zu installierenden Icons ist ein existierendes Verzeichnis. Das Icon wird deshalb ausgelassen.")
  95. (set #gad_yes                   "Ja")
  96. (set #gad_no                    "Nein")
  97. (set #gad_opt_typ               "Icon-Typ")
  98. (set #gad_opt_tooltype          "Merkmale")
  99. (set #gad_opt_position          "Position")
  100. (set #gad_opt_deftool           "Standard-Programm")
  101. (set #gad_opt_stack             "Stack-Größe")
  102. (set #gad_opt_force             "Nur schon existierende Icons")
  103. (set #msg_makebackup            "Erstelle Backup einer Datei...")
  104. (set #msg_requirements          (CAT "Willkommen zum Installationsskript vom FreshIcons-Set - " #set_name"\nEs sind zuvor folgende Bedingungen zu erfüllen:\n\nNö, keine. (Glück gehabt)"))
  105. (set #msg_updateicon            "Modifiziere Icon...")
  106. (set #msg_installnewicon        "Installiere neues Icon...")
  107. (set #msg_broken                (CAT #set_name "-IconSet Installation wurde abgebrochen!"))
  108. (set #msg_copyicon              "Ein Icon wird kopiert...")
  109. (set #help_backup               "Geben Sie hier an, ob alle Icons die verändert werden vorher nocheinmal zu Sicherheit woanders gespeichert werden sollen.")
  110. (set #help_WhereToBackup        "Geben Sie hier das Verzeichnis an, in dem alle Icons, die durch diese Installation verändert werden, gesichert werden sollen.")
  111. (set #help_WhereFreshIcons      "Geben Sie hier das Hauptverzeichnis der FreshIcons an.\nHaben Sie das FreshIcons-Paket komplett installiert und kein Verzeichnis woanders hinkopiert/verschoben, so müßte hier das richtige Verzeichnis bereits angezeigt werden.")
  112. (set #help_WherePackage         (CAT "Hier sollen Sie den Pfad angeben, in dem Sie " #set_name " installiert haben."))
  113. (set #help_requirements         "Holla! Erfüllen sie irgendwie und unbedingt die Bedingungen!")
  114. (set #help_Options              "Geben Sie hier die Eigenschaften an, welche\naus dem Set für die Icons übernommen werden sollen.")
  115. )
  116. ;/*E*/
  117. ;/*S*/ Temp-Stuff
  118. ;/*S*/ UP: Find path to a temporary directory
  119. (procedure P_maketemp
  120.     (if (<> (exists ("T:") (noreq) ) 2)
  121.         ;// then
  122.         (if (<> (exists ("Ram:T")) 2)
  123.             (
  124.                 (makedir ("ram:t"))
  125.                 (if (<>(exists ("ram:t")) 2)
  126.                     (message #err_notemploc)
  127.                     (set #temp "ram:")
  128.                 )
  129.             )
  130.             (set #temp "ram:t") ;// else "ram:t" exists
  131.         )
  132.         ;// else
  133.         (set #temp "T:") ;// else "T:" exists
  134.     )
  135.  
  136.     (set #temp (tackon #temp "freshicons_temp/"))
  137.  
  138.     (makedir #temp)
  139.     (if (<> (exists #temp) 2)
  140.         (abort #err_nomakedir)
  141.     )
  142.  
  143.     ;// Default backup-pfad
  144.     (trap 255 P_CleanUp)
  145. )
  146. ;/*E*/
  147. ;/*S*/ UP: Empties the temp-directory
  148. (procedure P_cleartemp
  149.     (run
  150.         (cat "delete " "force " "all " "quiet " (tackon #temp "#?"))
  151.     )
  152. )
  153. ;/*E*/
  154. ;/*S*/ UP: Deletes the temp-directory
  155. (procedure P_deletetemp
  156.     (run
  157.         (cat "delete " "force " "all " "quiet " #temp)
  158.     )
  159. )
  160. ;/*E*/
  161. ;/*S*/ UP: CleansUp the temp-directory
  162. (procedure P_CleanUp
  163.     (
  164.         (P_cleartemp)
  165.         (P_deletetemp)
  166.     )
  167. )
  168. ;/*E*/
  169. ;/*E*/
  170. ;/*S*/ UP: Asks for the name of the backup-path
  171. (PROCEDURE P_AskBackUp
  172.     ;// determine wether the user wants to make backups
  173.     (IF (ASKBOOL
  174.             (PROMPT #ask_backup)
  175.             (CHOICES #gad_yes #gad_no)
  176.             (HELP #help_backup)
  177.         )
  178.         ;//then
  179.         (SET #f_Backup 1)
  180.         ;//else
  181.         (SET #f_Backup 0)
  182.     )
  183.  
  184.     ;// wenn das Verzeichnis nicht existiert
  185.     (IF (= (EXISTS (TACKON #dos_backup_dest "FreshIcons_Baks")) 2)
  186.         (set #dos_backup_dest (TACKON #dos_backup_dest "FreshIcons_Baks"))
  187.     )
  188.     ;// if the User wants one
  189.     (IF (= 1 #f_Backup)
  190.         ;// then
  191.         (
  192.             ;// Ask for the backup-drawer
  193.             (SET #dos_backup_dest (ASKDIR
  194.                     (PROMPT #ask_WhereToBackup)
  195.                     (HELP #help_wheretobackup)
  196.                     (DEFAULT #dos_backup_dest)
  197.                 )
  198.             )
  199.             ;// append the name of the Software-package
  200.             (SET #dos_backup_dest (CAT (TACKON #dos_backup_dest #set_name) "_icons"))
  201.             ;// Create the wanted drawer
  202.             (MAKEDIR #dos_backup_dest )
  203.         )
  204.     )
  205. )
  206. ;/*E*/
  207. ;/*S*/ UP: Does the Backup of a given file
  208. (PROCEDURE P_DoBackup
  209.     ;// if a backup shall really be made
  210.     (if (= #f_Backup 1)
  211.         ;// test whether the source exists
  212.         (if (= (exists (tackon #dos_destination #dos_backupfile) (noreq) ) 1)
  213.             ;// if it exists
  214.             (
  215.                 ;// copy the source to the backup-drawer
  216.                 (COPYFILES
  217.                     (PROMPT #msg_makebackup)
  218.                     (SOURCE (tackon #dos_destination #dos_backupfile))
  219.                     (DEST   (tackon #dos_backup_dest (pathonly #dos_backupfile)))
  220.                 )
  221.             )
  222.         )
  223.     )
  224. )
  225. ;/*E*/
  226. ;/*S*/ UP: AskFreshDrawer
  227. (PROCEDURE P_AskFreshDrawer
  228. (set #temp_defpath "")
  229.  
  230.     (IF (= (EXISTS "SYS:System/FreshIconsV1.1" (noreq) ) 0)
  231.         ;//then
  232.         (
  233.             (IF (= (EXISTS "SYS:System/FreshIcons" (noreq) ) 0)
  234.                 ;// then
  235.                 (set #temp_defpath (expandpath "///"))
  236.                 ;// else
  237.                 (set #temp_defpath "SYS:System/FreshIcons")
  238.             )
  239.         )
  240.         ;//else
  241.         (set #temp_defpath "SYS:System/FreshIconsV1.1")
  242.     )
  243.     ;// Ask for the FreshIcons-Drawer
  244.     (SET #temp_defpath (askdir
  245.             (prompt #ask_WhereFreshIcons)
  246.             (help #help_whereFreshIcons)
  247.             (default #temp_defpath)    ;// often this is the right way to find it
  248.         )
  249.     )
  250. )
  251. ;/*E*/
  252. ;/*S*/ UP: Find the tool directory
  253. (PROCEDURE P_FindToolDir
  254. (set #temp_defpath (expandpath #dos_toolsdir))
  255.     (IF (= (EXISTS (tackon #temp_defpath "updateicon" ) (noreq) ) 0)
  256.         ;//then
  257.         (
  258.             (set #temp_defpath "c:" )
  259.             (IF (= (EXISTS (tackon #temp_defpath "updateicon" ) (noreq) ) 0)
  260.                 ;// then
  261.                 (
  262.                     (P_AskFreshDrawer)
  263.                     (set #temp_defpath (tackon #temp_defpath "c/"))
  264.  
  265.                     (IF (= (EXISTS (tackon #temp_defpath "updateicon" ) (noreq) ) 0)
  266.                         ;// then
  267.                         (ABORT #err_no_updateicon)
  268.                     )
  269.                 )
  270.                 ;// else
  271.             )
  272.         )
  273.         ;//else
  274.     )
  275.     (set #dos_toolsdir #temp_defpath)
  276. )
  277. ;/*E*/
  278. ;/*S*/ UP: AskOptions
  279. (PROCEDURE P_AskOptions
  280.     (set #b_options
  281.         (ASKOPTIONS
  282.             (PROMPT #ask_options)
  283.             (CHOICES
  284.                 #gad_opt_typ
  285.                 #gad_opt_tooltype
  286.                 #gad_opt_position
  287.                 #gad_opt_deftool
  288.                 #gad_opt_stack
  289.                 #gad_opt_force
  290.             )
  291.             (default (+ 6 (* 32 #f_onlyexisting)))
  292.             (help #help_Options)
  293.         )
  294.     )
  295.     (IF (IN #b_options 0)
  296.         (set #updateicon_opts (CAT #updateicon_opts " TYPE=2"))
  297.         (set #updateicon_opts (CAT #updateicon_opts " TYPE=0"))
  298.     )
  299.     (IF (IN #b_options 1)
  300.         (set #updateicon_opts (CAT #updateicon_opts " TOOLTYPES=2"))
  301.         (set #updateicon_opts (CAT #updateicon_opts " TOOLTYPES=0"))
  302.     )
  303.     (IF (IN #b_options 2)
  304.         (set #updateicon_opts (CAT #updateicon_opts " POSITION=2"))
  305.         (set #updateicon_opts (CAT #updateicon_opts " POSITION=0"))
  306.     )
  307.     (IF (IN #b_options 3)
  308.         (set #updateicon_opts (CAT #updateicon_opts " DEFTOOL=2"))
  309.         (set #updateicon_opts (CAT #updateicon_opts " DEFTOOL=0"))
  310.     )
  311.     (IF (IN #b_options 4)
  312.         (set #updateicon_opts (CAT #updateicon_opts " STACKSIZE=2"))
  313.         (set #updateicon_opts (CAT #updateicon_opts " STACKSIZE=0"))
  314.     )
  315.  
  316.     (IF (IN #b_options 5)
  317.         (set #f_onlyexisting 1)
  318.         (set #f_onlyexisting 0)
  319.     )
  320. )
  321. ;/*E*/
  322. ;/*S*/ UP: AskSys
  323. (PROCEDURE P_AskSys
  324.     ;// Ask for Software-Package-Drawer
  325.     (SET #dos_destination (askdir
  326.             (prompt #ask_WherePackage)
  327.             (help #help_wherepackage)
  328.             (default (expandpath #dos_destination))
  329.         )
  330.     )
  331. )
  332. ;/*E*/
  333. ;/*S*/ UP: DoFile
  334. (PROCEDURE P_DoFile
  335.     ;// append ".info"
  336.     (SET #dos_filename_i (cat #dos_filename ".info"))
  337.     ;// set up the name of the backupfile- with the icon-filename
  338.     (SET #dos_backupfile #dos_filename_i)
  339.  
  340.     ;// do the backup if wanted
  341.     (P_DoBackUp)
  342.  
  343.     ;// Test the existing of the destination-icon
  344.     (IF (= (EXISTS (cat (TACKON #dos_destination #dos_filename_i) ) (noreq) ) 1)
  345.         ;// then ( if the icon to be modified does exist )
  346.         (
  347.             ;// set up the updateicon-command for the run statement in a variable
  348.             (SET #dos_args
  349.                 (cat "\"" (tackon #dos_toolsdir "UpDateIcon" ) "\""
  350.                      " SOURCE=\"" #dos_source "\" DESTINATION=\"" (TACKON #dos_destination #dos_filename) "\"" #updateicon_opts
  351.                 )
  352.             )
  353.  
  354.             ;// for debugging...
  355.             ;(message #dos_args)
  356.  
  357.             ;// now call the updateicon-program to do the real update
  358.             (RUN #dos_args
  359.                 (PROMPT (CAT #msg_updateicon "\n\n" #dos_filename))
  360.             )
  361.         )
  362.         ;// else ( if the icon to be modified, doesnt exist )
  363.         (
  364.             ;// if it is wanted to copy a icon doesnt exist in the software package yet
  365.             (IF (= #f_onlyexisting 0)
  366.                 ;// then
  367.                 (
  368.                     (SET #dos_source_i (cat #dos_source ".info"))
  369.                     (SET #dos_tempdest (TACKON #dos_destination (PATHONLY #dos_filename_i)))
  370.  
  371.                     ;// for debugging:
  372.                     ;(message (cat "Source:" #dos_source_i) )
  373.                     ;(message (cat "Dest:" (tackon #dos_destination (pathonly #dos_filename_i) )))
  374.                     ;(message (cat "Dir-Exist-Test:" (TACKON #dos_destination #dos_filename_i)))
  375.  
  376.                     ;// if the dest-icon-name is no existing directory
  377.                     (IF (<> (EXISTS (TACKON #dos_destination #dos_filename_i) (noreq) ) 2)
  378.                         ;// copy the files
  379.                         (COPYFILES
  380.                             (PROMPT (CAT #msg_installnewicon "\n\n\"" #dos_filename "\"" ))
  381.                             (SOURCE #dos_source_i)
  382.                             (DEST   #dos_tempdest)
  383.                         )
  384.                         ;// else
  385.                         (
  386.                             (MESSAGE #err_desticonisdir)
  387.                         )
  388.                     )
  389.                 )
  390.             )
  391.         )
  392.     )
  393. )
  394. ;/*E*/
  395. ;/*E*/
  396. ;---------------------------------------------------------
  397. ;/*S*/ ### Main ###
  398.     ;// Find out in which language to install
  399.     (IF (= @language "deutsch")
  400.         ;// then
  401.         (P_germaninstall)
  402.         ;// else
  403.         (P_englishinstall)
  404.     )
  405.  
  406.     ;// check the installer version...
  407.     (IF (<= @installer-version 0)
  408.         (abort #err_wronginstaller)
  409.     )
  410.  
  411.     ;// if this scripts has requirements
  412.     (IF (= #f_requirements 1)
  413.         ;// You should tell the user here, what is needed for this installation-script
  414.         (MESSAGE #msg_requirements
  415.             (help #help_requirements)
  416.         )
  417.     )
  418.  
  419. (COMPLETE 1)
  420.     ;// Ladies & Gentlemen...
  421.     (WELCOME)
  422.  
  423. (COMPLETE 5)
  424.     ;// Find the path to the perhaps-needed temporary path
  425.     (P_maketemp)
  426.  
  427.     ;// if something goes wrong later...
  428.     (ONERROR (
  429.             (P_CleanUp)
  430.             (EXIT
  431.                 #msg_broken
  432.                 (quiet)
  433.             )
  434.         )
  435.     )
  436.  
  437. (COMPLETE 10)
  438.     ;// find installed FreshIcons drawer
  439.     (P_FindToolDir)
  440.  
  441. (COMPLETE 15)
  442.     ;// find Software-path
  443.     (P_AskSys)
  444.  
  445. (COMPLETE 25)
  446.     ;// make clear the backup question
  447.     (P_AskBackup)
  448.  
  449. (COMPLETE 40)
  450.     ;// Ask for the options
  451.     (P_AskOptions)
  452.  
  453. (COMPLETE 45)
  454.     ;// State that we do something
  455.     (WORKING #msg_installnewicon)
  456.  
  457.     ;// determine the complete source drawer-name
  458.     (SET #dos_presource (expandpath (CAT #set_name "_Icons")))
  459.  
  460.     ;// Now the icons are to be updated...
  461. ;///////////////////////////////////////////////////////////////////////////
  462. ;// repeat this for every file!
  463. (COMPLETE 50)
  464.     (SET #dos_filename "Docs")                       
  465.     (SET #dos_source (TACKON #dos_presource "Docs")) 
  466.     (P_DoFile)                                       
  467. (COMPLETE 51)
  468.     (SET #dos_filename "Demos")                       
  469.     (SET #dos_source (TACKON #dos_presource "Demos")) 
  470.     (P_DoFile)                                       
  471. (COMPLETE 52)
  472.     (SET #dos_filename "Developer")                       
  473.     (SET #dos_source (TACKON #dos_presource "Developer")) 
  474.     (P_DoFile)                                       
  475. (COMPLETE 53)
  476.     (SET #dos_filename "Goodies")                       
  477.     (SET #dos_source (TACKON #dos_presource "Goodies")) 
  478.     (P_DoFile)                                      
  479. (COMPLETE 54)
  480.     (SET #dos_filename "Icons")                      
  481.     (SET #dos_source (TACKON #dos_presource "Icons")) 
  482.     (P_DoFile)                                       
  483. (COMPLETE 55)
  484.     (SET #dos_filename "Images")                       
  485.     (SET #dos_source (TACKON #dos_presource "Images")) 
  486.     (P_DoFile)                                       
  487. (COMPLETE 56)
  488.     (SET #dos_filename "Libs")                        
  489.     (SET #dos_source (TACKON #dos_presource "Libs")) 
  490.     (P_DoFile)                                       
  491. (COMPLETE 57)
  492.     (SET #dos_filename "Liesmich")                        
  493.     (SET #dos_source (TACKON #dos_presource "LiesMich"))  
  494.     (P_DoFile)                                       
  495. (COMPLETE 58)
  496.     (SET #dos_filename "Locale")                        
  497.     (SET #dos_source (TACKON #dos_presource "Locale"))  
  498.     (P_DoFile)                                        
  499. (COMPLETE 59)
  500.     (SET #dos_filename "MUI")                        
  501.     (SET #dos_source (TACKON #dos_presource "MUI"))  
  502.     (P_DoFile)                                        
  503. (COMPLETE 60)
  504.     (SET #dos_filename "Patterns")                        
  505.     (SET #dos_source (TACKON #dos_presource "Patterns"))  
  506.     (P_DoFile)                                        
  507. (COMPLETE 61)
  508.     (SET #dos_filename "Presets")                        
  509.     (SET #dos_source (TACKON #dos_presource "Presets"))  
  510.     (P_DoFile)                                        
  511. (COMPLETE 62)
  512.     (SET #dos_filename "PSI")                        
  513.     (SET #dos_source (TACKON #dos_presource "PSI"))  
  514.     (P_DoFile)                                       
  515. (COMPLETE 63)
  516.     (SET #dos_filename "Rexx")                        
  517.     (SET #dos_source (TACKON #dos_presource "Rexx"))  
  518.     (P_DoFile)                                        
  519. (COMPLETE 64)
  520.     (SET #dos_filename "/MUI")                        
  521.     (SET #dos_source (TACKON #dos_presource "/MUI_Icons"))  
  522.         (P_DoFile)
  523. ;//////////////////////////////////////////////////////////////////////////
  524.  
  525.     ;// the same for the next and so on...
  526.  
  527. (COMPLETE 90)
  528.     ;// for the graceful exit
  529.     (SET @default-dest #dos_destination)
  530.     (P_CleanUp)
  531. (COMPLETE 100)
  532. ;/*E*/
  533.  
  534.